通达信公式二
(2016-12-12 09:51:29)
MACD 涨停选股公式
MACD副图，参考抓板时用。
指标用法：当指标出现小绿箭头，但是第二天出现红箭头，可以80%确定是诱空信号，而且3天内涨停概率很大。反之，当出现红箭头，第二天出现绿箭头，诱多信号，先清仓离场。
MACD出现黄柱代表可能要变盘（多变空）。
DIFF:=EMA(CLOSE,9) - EMA(CLOSE,50);
DEA1:=EMA(DIFF,2);
MACD:=2*(DIFF-DEA1),LINETHICK0;
SS1:=MACD<REF(MACD,1)AND MACD>0;
SS2:=MACD<REF(MACD,1)/2 AND MACD<0;
DEA:=EMA(DIFF,2),COLORGREEN;
CROSS(DIFF,DEA) AND REF(CROSS(DEA,DIFF),1);
{找10天内缩量下跌后盘整的股票，涨幅过大股票不要，0轴以下的优选！};
------------------------------------------------------
MACD 涨停指标公式：
STICKLINE(MACD<REF(MACD,1)AND MACD>0,0,MACD,2,0 ),COLOR00BBFF;
STICKLINE(MACD<REF(MACD,1)AND MACD>0,0,MACD,1,0 ),COLOR00DDFF;
STICKLINE(MACD<REF(MACD,1)AND MACD>0,0,MACD,0,0 ),COLOR00FFFF;
STICKLINE(MACD>=REF(MACD,1)AND MACD>0,0,MACD,2,0 ),COLOR0011EE;
STICKLINE(MACD>=REF(MACD,1)AND MACD>0,0,MACD,1,0 ),COLOR0033DD;
STICKLINE(MACD>=REF(MACD,1)AND MACD>0,0,MACD,0,0 ),COLOR0055FF;
STICKLINE(MACD>REF(MACD,1)AND MACD<0,0,MACD,2,0 ),COLORBB11BB;
STICKLINE(MACD>REF(MACD,1)AND MACD<0,0,MACD,1,0 ),COLORDD33BB;
STICKLINE(MACD>REF(MACD,1)AND MACD<0,0,MACD,0,0 ),COLORFF55BB;
STICKLINE(MACD<=REF(MACD,1)AND MACD<0,0,MACD,2,0 ),COLORFFBB11;
STICKLINE(MACD<=REF(MACD,1)AND MACD<0,0,MACD,1,0 ),COLORFFDD33;
STICKLINE(MACD<=REF(MACD,1)AND MACD<0,0,MACD,0,0 ),COLORFFFF55;
DIFF:=EMA(CLOSE,9) - EMA(CLOSE,50);
DEA1:=EMA(DIFF,2);
0.10,POINTDOT;
MACD:=2*(DIFF-DEA1),LINETHICK0;
SS1:=MACD<REF(MACD,1)AND MACD>0;
SS2:=MACD<REF(MACD,1)/2 AND MACD<0;
STICKLINE(MACD>=0,MACD,0,3,1),COLORRED;
STICKLINE(SS1,0,MACD,3,1),COLOR00FFFF;
STICKLINE(SS2,0,MACD,3,0),COLORFFFFFF;
STICKLINE(MACD>REF(MACD,1)AND MACD<0,0,MACD,3,1),COLORFFFF00;
DEA:EMA(DIFF,2),COLORGREEN;
IF(DIFF>DEA,DIFF,DRAWNULL),COLORFF11CC,LINETHICK2;
IF(DIFF>DEA AND DIFF<0,DIFF,DRAWNULL),COLORRED,LINETHICK2;
DRAWICON(CROSS(DIFF,DEA),DIFF-0.1,1);
DRAWICON(CROSS(DEA,DIFF),DIFF+0.1,2);
MAC:3*DIFF-2*DEA1,LINETHICK1,COLORRED;
VAR1:=EMA(CLOSE,3)-EMA(CLOSE,4);
VAR2:=EMA(VAR1,2);
趋势:=(-3)*(VAR1-VAR2);
VAR11:=MA((V/(H-L)),4);
VAR33:=ABS(C-O);
VAR44:=V/(H-L);
TRR := SUM(MA(MA(HIGH-LOW,ABS(HIGH-REF(CLOSE,1))),ABS(LOW-REF(CLOSE,1))),5);
HD := HIGH-REF(HIGH,1);
LD := REF(LOW,1)-LOW;
DMP:= SUM(IF(HD>0 AND HD>LD,HD,0),5);
DMM:= SUM(IF(LD>0 AND LD>HD,LD,0),5);
PDI:= DMP*100/TR;
MDI:= DMM*100/TR;
ADX:= MA(ABS(MDI-PDI)/(MDI+PDI)*100,5);
ADXR:=(ADX+REF(ADX,5))/2;
W1:=CROSS(MA(C,10),MA(C,5)) ;
W2:=CROSS(MA(C,5),MA(C,10)) ;
W3:=CROSS(MA(V,10),MA(V,5));
W4:=CROSS(DEA,DIFF);
W11:=C<=MA(C,5) AND C<=MA(C,10) ;
W22:=O>MA(C,3) AND O>MA(C,5) ;
W33:=MA(V,2)<=MA(V,3);
W44:=DIFF<DEA;
W5:=VOL;
DRAWTEXT(W11 AND W22 AND W33 AND W44,DIFF,'＃'),COLORFFFF10;
LC := REF(CLOSE,1);
PSY:=COUNT(CLOSE>REF(CLOSE,1),12)/12*100;
AA:=(EMA(C,10)*2+MA(C,20))/3;
RA:=(VOL*CLOSE);
VL1A:=EMA(RA,13)/EMA(VOL,13);
VL2A:=EMA(RA,20)/EMA(VOL,20);
VLA:=EMA((VL1A+VL2A)/2,3);
分水岭:=MA((AA+VLA)/2,1),LINETHICK0;
BBI:=(MA(CLOSE,3)+MA(CLOSE,6)+MA(CLOSE,12)+MA(CLOSE,24))/4;
UPR:=BBI+3*STD(BBI,10);
DWN:=BBI-3*STD(BBI,10);
VAR55:=(UPR-DWN)/UPR<0.03;
VAR56:=(UPR-DWN)/UPR>0.18;
VAR57:=(MA(C,20)-MA(C,5))/MA(C,20)>0.15;
VAR58:=(MA(C,5)-MA(C,60))/MA(C,5)>0.15;
S1:=趋势>0; S2:=趋势<0; S3:=CROSS(趋势,0); S4:=CROSS(0,趋势);
S5:=CROSS(PDI,MDI); S6:=CROSS(MDI,PDI); S7:=ADX>REF(ADX,1); S8:=W11 AND W22;
S9:=W1; S10:=W3; S11:=W4; S12:=W11 AND W22 AND W33 AND W44;
S13:=W11 AND W33 AND W44; S14:=W5>0.075;
S20:=CLOSE>分水岭;
S21:=CLOSE<分水岭; S22:=VAR55; S23:=VAR57 AND VAR56;
E1:=IF(S1=1 ,-0.08,-0.08);
E2:=IF(S2=1,E1+0.1,E1);
E3:=IF(S3=1,E2+0.1,E2);
E4:=IF(S4=1,E3+0.1,E3);
E5:=IF(S5=1,E4+0.1,E4);
E6:=IF(S6=1,E5+0.1,E5);
E7:=IF(S7=1,E6+0.1,E6);
E8:=IF(S8=1,E7+0.1,E7);
E9:=IF(S9=1,E8+0.1,E8);
E10:=IF(S10=1,E9+0.1,E9);
E11:=IF(S11=1,E10+0.1,E10);
E12:=IF(S12=1,E11+0.1,E11);
E13:=IF(S13=1,E12+0.1,E12);
E14:=IF(S14=1,E13+0.1,E13);
DRAWTEXT_FIX(ISLASTBAR AND S1=1,0,E1,0,'Z线趋势上升中');
DRAWTEXT_FIX(ISLASTBAR AND S2=1,0,E2,0,'Z线趋势下降中');
DRAWTEXT_FIX(ISLASTBAR AND S4=1,0,E4,0,'Z线考虑卖出');
DRAWTEXT_FIX(ISLASTBAR AND S5=1,0,E5,0,'PDI突破MDI，有新多进场');
DRAWTEXT_FIX(ISLASTBAR AND S6=1,0,E6,0,'PDI跌破MDI，有新空进场');
DRAWTEXT_FIX(ISLASTBAR AND S8=1,0,E8,0,'断头铡刀:,卖出'),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR AND S9=1,0,E9,0,'5日死叉10均线,短线卖出');
DRAWTEXT_FIX(ISLASTBAR AND S10=1,0,E10,0,'5日死叉10日均量,卖出');
DRAWTEXT_FIX(ISLASTBAR AND S11=1,0,E11,0,'DIFF下穿DEA,空头形成,卖出');
DRAWTEXT_FIX(ISLASTBAR AND S12=1,0,E12,0,'三死叉见顶,卖出'),COLORFF00FF;
DRAWTEXT_FIX(ISLASTBAR AND S13=1,0,E13,0,'多方溃败,卖出'),COLORGREEN;
DRAWTEXT_FIX(ISLASTBAR AND S14=1,0,E14,0,'小心主力出逃');
X_1:=IF(DATE<1191130,1,0);
X_2:=BARSLAST(REF(MACD,1)<0 AND MACD>0);
X_3:=LLVBARS(MACD,X_2+20);
X_4:=IF(X_3>X_2,REF(MACD,X_3),0);
X_5:=MACD<0 AND MACD>X_4 AND LOW=LLV(LOW,X_2+20) AND X_4<0;
X_6:=REF(X_5,1)=1 AND MACD>REF(MACD,1) AND REF(DIFF,X_3)<0 AND MACD<0;
低背:DRAWLINE(X_4=X_3,MACD,X_6,MACD,0),COLORRED,LINETHICK2;
DRAWICON(X_6,MACD*1.2,26);
X_7:=HHVBARS(MACD,X_2+20);
X_8:=IF(X_7>X_2,REF(MACD,X_7),0);
X_9:=MACD>0 AND MACD<X_8 AND HIGH=HHV(HIGH,X_2+20) AND X_8>0;
X_10:=REF(X_9,1)=1 AND MACD>REF(MACD,1) AND REF(DIFF,X_7)>0;
顶背:DRAWLINE(X_8=X_7,MACD,X_10,MACD,0),COLORGREEN,LINETHICK2;
DRAWICON(X_10,MACD*1.2,15);
X_11:=CLOSE/MA(CLOSE,40)*100<78;
X_12:=CLOSE/MA(CLOSE,60)*100<74;
X_13:=HIGH>LOW*1.051;
X_14:=X_13 AND COUNT(X_13,5)>1;
X_15:=IF(X_14 AND (X_11 OR X_12),2,0);
X_16:=CLOSE/REF(CLOSE,25)<=1.1;
X_17:=SMA(MAX(CLOSE-REF(CLOSE,2),0),7,1)/SMA(ABS(CLOSE-REF(CLOSE,2)),7,1)*100<15;
X_18:=(CLOSE-LLV(LOW,8))/(HHV(HIGH,8)-LLV(LOW,8))*100;
X_19:=SMA(X_18,2,1);
X_20:=SMA(X_19,2,1);
X_21:=IF(X_19>REF(X_19,1) AND REF(X_19,1)<REF(X_19,2) AND X_19<23,1.5,0);
抄底:X_16 AND X_15 AND X_17 AND X_21 AND X_1=1,COLORWHITE;
================================
MACD看透主力：
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
VA:=IF(CLOSE>REF(CLOSE,1),VOL,-VOL);
OBV1:=SUM(IF(CLOSE=REF(CLOSE,1),0,VA),0);
OBV2:=EMA(OBV1,3)-MA(OBV1,9);
OBV3:=EMA(IF(OBV2>0,OBV2,0),3);
MAC3:=MA(C,3);
SHORT:=12;LONG:=26;MID:=9;
DIF:EMA(CLOSE,SHORT)-EMA(CLOSE,LONG)COLORYELLOW ;
DEA:EMA(DIF,MID)COLORFF9900 ;
主力买:IF(DIF>REF(DIF,1),DIF,0),NODRAW;
主力卖:IF(DIF<REF(DIF,1),DIF,0),NODRAW;
MACD:=(DIF-DEA)*2;
STICKLINE(OBV3>REF(OBV3,1) AND MAC3>REF(MAC3,1),0,MACD,1.2,0),COLORYELLOW;
吸:=MACD<0 AND MACD>REF(MACD,1);
拉:=MACD>0 AND MACD>REF(MACD,1);
派:=MACD>0 AND MACD<REF(MACD,1);
落:=MACD<0 AND MACD<REF(MACD,1);
STICKLINE(吸,0,MACD,0.5,0),COLORRED;
STICKLINE(拉,0,MACD,0.5,0),COLORRED;
STICKLINE(派,0,MACD,0.5,0),COLORGREEN;
STICKLINE(落,0,MACD,0.5,0),COLORWHITE;
主力吸筹:吸,COLORYELLOW,NODRAW;
主力拉升:拉,COLORRED,NODRAW;
主力派送:派,COLORGREEN,NODRAW;
主力砸盘:落,COLORFFAA00,NODRAW;
JCCOUNT:=COUNT(CROSS(DIF,DEA),BARSLAST(DEA>=0));
低位金叉:CROSS(DIF,DEA) AND DIF<-0.1,COLORWHITE,NODRAW;
二次金叉:CROSS(DIF,DEA) AND DEA<0 AND COUNT(JCCOUNT=2,21)=1,COLORRED,NODRAW;
STICKLINE(低位金叉,0,0.08,2,0),COLORFF00FF;
DRAWTEXT(低位金叉,0.16,' 低位金叉'),COLORWHITE;
A1:=BARSLAST(REF(CROSS(DIF,DEA),1));
A2:=BARSLAST(REF(CROSS(DEA,DIF),1));
底背离:REF(CLOSE,A1+1)>CLOSE AND DIF>REF(DIF,A1+1) AND CROSS(DIF,DEA),COLORGREEN,NODRAW;
STICKLINE(底背离,0,0.03,2,0),COLOR00FF00;
DRAWTEXT(底背离,0.12,'底背离'),COLORFF00FF;
双金叉:低位金叉 AND 二次金叉,COLORFF00FF,NODRAW;
三全项:低位金叉 AND 二次金叉 AND 底背离,COLORWHITE ,NODRAW;
顶背离:=REF(CLOSE,A2+1)<CLOSE AND REF(DIF,A2+1)>DIF AND CROSS(DEA,DIF);
STICKLINE(二次金叉,0,0.06,2,0),COLORFFCC00;
DRAWICON(二次金叉,DEA*0.9,1) ;
DRAWTEXT(二次金叉,0.2,' 二次金叉'),COLORYELLOW;
DRAWTEXT(低位金叉 AND 二次金叉 AND 底背离,0.25,'三全项'),COLOR0000FF,LINETHICK2;
IF(DIF>REF(DIF,1),DIF,DRAWNULL),COLORRED,LINETHICK2;
IF(DIF<REF(DIF,1),DIF,DRAWNULL),COLORGREEN,LINETHICK2;
（end）
==================================================
MACD自动画线：
~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
{OBV:=DIF; ----MACD画线
N:=2,500,21;
M:2,30,11;}
DIF:EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:EMA(DIF,9);
MACD:(DIF-DEA)*2,COLORSTICK;
OBV:=DIF;
P:=5;
A1:=REF(OBV,P)=HHV(OBV,2*P+1);{A1赋值:P日前的OBV=2*P+1日内OBV的最高值}
B1:=FILTER(A1,P);{A1的P日过滤}
C1:=BACKSET(B1,P+1);{若B1则将最近P+1周期置为1}
D1:=FILTER(C1,P);{高点,C1的P日过滤}
A2:=REF(OBV,P)=LLV(OBV,2*P+1);
B2:=FILTER(A2,P);
C2:=BACKSET(B2,P+1);
D2:=FILTER(C2,P);{低点}
上:REF(OBV,BARSLAST(D1)),COLORRED,NODRAW;
下:REF(OBV,BARSLAST(D2)),COLORYELLOW,NODRAW;
R11:=BACKSET(ISLASTBAR,BARSLAST(D1)+1);
S11:=R11>REF(R11,1);
DRAWLINE(D1,OBV,S11,OBV,1),COLORYELLOW;
{当满足条件D1时,在OBV位置画直线起点，
当满足条件S11时,在OBV位置画直线终点,1表示是否延长.,画黄色}
T11:=BACKSET(ISLASTBAR,BARSLAST(D2)+1);
U11:=T11>REF(T11,1);
DRAWLINE(D2,OBV,U11,OBV,1),COLORRED;
STICKLINE(C>0,下,下,1,0),COLOR00FF00;
STICKLINE(C>0,上,上,1,0),COLORFF00FF;
DRAWTEXT(CROSS(OBV,上*1.01),上,'上'),COLORYELLOW;
DRAWTEXT(CROSS(下*0.99,OBV),下,'下'),COLORYELLOW;
DRAWICON(D1,OBV,2);
DRAWICON(D2,OBV,1);
{以下是金X提示}
DIFF1:=EMA(CLOSE,12)-EMA(CLOSE,27);
DEA1:=EMA(DIFF1,9);
强度:IF(DIFF1>=DEA1,DIFF1,DRAWNULL),COLORRED;
金叉:=CROSS(DIFF1,DEA1) AND DIFF1<-0.1;
DRAWTEXT(金叉,-0.1,' 低金'),COLORYELLOW;
JCCOUNT:=COUNT(CROSS(DIFF1,DEA1),BARSLAST(DEA1>=0));
二金:=CROSS(DIFF1,DEA1) AND DEA1<0 AND COUNT(JCCOUNT=2,21)=1;
DRAWICON(二金,DEA1*1.04,13) ;
DRAWTEXT(二金,-0.1,' 二金'),COLORFF00FF;
AB1:=BARSLAST(REF(CROSS(DIFF1,DEA1),1));
底背离:=REF(CLOSE,AB1+1)>CLOSE AND DIFF1>REF(DIFF1,AB1+1) AND CROSS(DIFF1,DEA1);
底背:DRAWLINE(AB1=0,DEA1,底背离,DEA1,0),COLORRED,POINTDOT;
DRAWTEXT(底背离,0.1,'底背'),COLORMAGENTA;
AB2:=BARSLAST(REF(CROSS(DEA1,DIFF1),1));
顶背离:=REF(CLOSE,AB2+1)<CLOSE AND REF(DIFF1,A2+1)>DIFF1 AND CROSS(DEA1,DIFF1);
顶背:DRAWLINE(AB2=0,DEA1,顶背离,DEA1,0),COLORGREEN,POINTDOT;
DRAWTEXT(顶背离,DIFF1,'顶背'),COLORGREEN;
（end）
{***********************
公式：均线53度仰角
描述：近5日内均线53度仰角选股
作者：股市肉鸡
日期：2013.04.15
参数：SHORT 3/100/5 LONG 8/100/10 ANGLE 15/90/53
************************}
均线53度仰角:BARSLAST(CROSS(MA(C,SHORT),MA(C,LONG)))<=5 AND (ATAN((MA(C,SHORT)/REF(MA(C,SHORT),1)-1)*100)*57.29578)>ANGLE;
=============
backset()函数的高级用法
~~~~~~~~~~~~~~~~~~~~~~~~~~
backset()函数的高级用法：
http://www.goomj.com/gsp/gsp2.htm
一、问题：如何在最后一根K线的前第6天，作上标记？
1、先建立一个名为backset-test的公式，代码如下：
islastbar{该周期是否最后一个周期。最后一个周期返回值为1，其余为0}
观察指标线的图形，正如注释所述，最后一天显示为1，这个1我们可理解为信号（条件）成立。其余时间，指标的数值为0，可理解为信号（条件）不成立。
2、巧用backset()函数：
①backset(x,n)注释：向前赋值，若X非0则把当前周期及前N－1周期的数值设置为1;
②示例：把信号向前移。
tj1:=islastbar;{最后一天的条件}
tj2:backset(tj1,6);
观察tj2指标线图，发现最后6天的tj2信号都是1，即一个高度为1的矩形。公式中，还无法判断哪天是倒数第6天。
3、显然倒数第6天，是上面矩形的前沿，如何在公式中，表达这个矩形的前沿？
容易想到的办法：
①倒数第6天的当天，tj2为1，更早的1天tj2=0，因此可以编出如下代码：
tj1:=islastbar;{最后一天的条件}
tj2:=backset(tj1,6);
tj3:tj2 and ref(tj2,1)=0;
②倒数第6天的当天，tj2为1，更早的1天tj2=0，即当天tj2比早一天的tj2更大，因此可以编出如下代码：
tj1:=islastbar;{最后一天的条件}
tj2:=backset(tj1,6);
tj3:tj2>ref(tj2,1);
③倒数第6天的当天，tj2为1，更早的1天tj2=0，可以想象为tj2指标线上穿了一条高度为0.5的水平线，因此可以编出如下代码：
tj1:=islastbar;{最后一天的条件}
tj2:=backset(tj1,6);
tj3:cross(tj2,0.5);
④巧用filter()过滤函数，filter(x,N)，若X非0，可以让X保持当天的值不变，且过滤其后N个周期使之数值为0。
tj1:=islastbar;{最后一天的条件}
tj2:=backset(tj1,6);
tj3:filter(tj2,5);{第1次的tj2保持为1不变，其后的5个周期过滤为0}
这样就初步找到了4种方法，可以标记倒数第6天，若想用图标来标记的话，代码例举如下：
tj1:=islastbar;{最后一天的条件}
tj2:=backset(tj1,6);
tj3:=tj2>ref(tj2,1);
drawicon(tj3,L,1);
本坛公式高手yyzzqq的精彩代码(macd金叉与死叉之间的最大值)
A1:=CROSS("MACD.MACD",0);
A2:=BARSLAST(A1);
A3:=HHVBARS("MACD.MACD" ,A2+1);
A4:=BACKSET(REF(A3>=1,1) AND "MACD.MACD"<0,A3);
A5:=BACKSET(REF(A4=0,1) AND A4=1,2);
最大值:IF(FILTER(A5,2),"MACD.MACD",0);
DRAWICON(最大值>0,最大值,1);
请教关于barslast函数的用法疑问？
引用函数barslast上一次条件成立到当前的周期，用法：barslast(x);上一次x不为0时到现在的天数。
问题如下：
tj:=barslast(c/ref(c,1)>1.09);
tj<10;上次条件成立日算不算，今天算不算；
tj>0;是否是指条件成立日的次日；
tj=1;是否是指当天条件，还是昨天条件；
tj+1;是否是指包括条件成立日当天；
tj+1<10;是否是条件成立日至今，如果不是条件成立日至今是不是用tj+1<=10表达；
ref(c,tj);加ref应该是求得条件成立当天收盘价；
在求涨幅时可加1如：(c-ref(c,tj+1))/ref(c,tj+1)*100对吗？
能否用ref(tj,1)表达条件上一个条件成立；
请各位高手指教，谢谢！！！
公式语句将在每一根K线上执行，正在执行的K线称当前K线。以下以"日线K线图"为例说明，说当前K线是 "今天"。
T:=barslast(x) ; 最近的条件x成立到当前K的（间隔）天数， T>=0，如果昨天x成立，T=1，今天成立，则T=0 。（如果以前的所有K线都不成立，T=drawnull。）
ref(y,0) 是今天的 y值，ref(y,1) 是昨天的 y值，ref(y,2) 是前天的 y值，... ref(y,T) 是最近的x成立那天的y 。
T1:=ref(T,1)，是在今天K线上计算T1，其值是在昨天K线计算出的T。 于是，如果T=5 , 则T1=4; 一般地，T1=T-1，只要T>0。
大智慧函数 BARSLAST(x) ，上上次条件成立周期数，要怎么写好？
http://www.55188.com/thread-5178046-1-1.html
请教高手一个问题，大智慧函数 BARSLAST(x) 是上次条件成立到当前的周期数，如果是上上次条件成立的周期数，不知道怎么表达。好像用BARSLAST(REF(X,1)) 不行啊。
举个例子：
A1：=MA(C,5);
A2：=MA(C,10);
B1：=CROSS(A1，A2);{A1，A2金叉}
T1：BARSLAST(B1);{上次金叉到当前的周期数}
如何求上上次，或更早之前的金叉到当前的周期数呢？？？？
T2：BARSLAST(REF(B1,1)); 这个好像不对。
====================
上次:=BARSLAST(b1) {
上上次:ref(BARSLAST(b1)+1,BARSLAST(b1)+1)+BARSLAST(b1)+1;
--------------------
我觉得改为下面的公式更准确：
T1:BARSLAST(b1);
T2:REF(T1,T1+1)+1+T1+1;
T3:REF(T1,T2)+1+T2 ;
T4:REF(T1,T3)+1+T3;
。。。。
T(N):REF(T1，T(N-1))+1+T(N-1);{N、N-1为序列，不是算式}
http://photo.blog.sina.com.cn/photo/2654157083/002TCzvdzy77exTPS3q64